筆者把量測CBR封包端點到端點間延遲時間的awk程式，寫在檔案measure-delay.awk檔案中，讀者可以參考此範例，修改成符合讀者需求的程式。

BEGIN {

#程式初始化，設定一變數以記錄目前最高處理封包的ID

highest_packet_id = 0;
}

{
   action = $1;
   time = $2;

   node_1 = $3;
   node_2 = $4;

   
type = $5;
   flow_id = $8; 
   node_1_address = $9;
   
node_2_address = $10; 
   seq_no = $11;
   packet_id = $12;
 

#記錄目前最高的packet ID
   if ( packet_id > highest_packet_id )

                highest_packet_id = packet_id;
 
#記錄封包的傳送時間


   if ( start_time[packet_id] == 0 )  
               start_time[packet_id] = time;
 
#記錄CBR (flow_id=2) 的接收時間
   
if ( flow_id == 2 && action != "d" ) {

      if ( action == "r" ) {

         end_time[packet_id] = time;
      }


   } else {
#把不是flow_id=2的封包或者是flow_id=2但此封包被drop的時間設為-1
      end_time[packet_id] = -1;

   }
}                                                                                                         
  

END {
#當資料列全部讀取完後，開始計算有效封包的端點到端點延遲時間 

    for ( packet_id = 0; packet_id <= highest_packet_id; packet_id++ ) {

       start = start_time[packet_id];
       end = end_time[packet_id];
       packet_duration = end - start;
 
#只把接收時間大於傳送時間的記錄列出來

       if ( start < end ) printf("%f %f\n", start, packet_duration);
   
}

}
 
執行方法: ($為shell的提示符號)

$awk -f measure-delay.awk 
out.tr

[Jitter]
Jitter 就是延遲時間變化量delay variance，由於網路的狀態隨時都在變化，有時候流量大，有時候流量小，當流量大的時候，許多封包就必需在節點的佇列中等待被傳送，因此每個封包從傳送端到目的地端的時間不一定會相同，而這個不同的差異就是所謂的Jitter。Jitter越大，則表示網路越不穩定。筆者把量測CBR flow的Jitter的awk寫在檔案measure-jitter.awk內。
 
BEGIN {
#程式初始化
   old_time=0;
   old_seq_no=0;
   i=0;
}
{
   action = $1;
   time = $2;
   node_1 = $3;
   node_2 = $4;
   type = $5;
   flow_id = $8;
   node_1_address = $9;
   node_2_address = $10;
   seq_no = $11;
   packet_id = $12;
  
#判斷是否為n2傳送到n3，且封包型態為cbr，動作為接受封包
   if(node_1==2 && node_2==3 && type=="cbr" && action=="r") {
#求出目前封包的序號和上次成功接收的序號差值
               dif=seq_no-old_seq_no;
 
#處理第一個接收封包
        if(dif==0)  
          dif=1;
 
#求出jitter
         jitter[i]=(time-old_time)/dif;
         seq[i]=seq_no;
                               i=i+1;
         old_seq_no=seq_no;
         old_time=time;
   }     
}
END {
   for (j=1; j <i ;j++)
    printf("%d\t%f\n",seq[j],jitter[j]);
}
 
執行方法: ($為shell的提示符號)
$awk -f measure-jitter.awk out.tr
 
若是要把結果存到檔案，可使用導向的方式。(把結果存到cbr_jitter檔案中)

$awk -f measure-jitter.awk 
out.tr > cbr_jitter

[另一種計算Jitter的方法---更精確的方式]
 
# ================================================================================
# NormalJitter.awk
# Version now: 0.1
# Last Modified Date: 2004-10-23,19:39:54 
# == Usage ==
# awk -f NormalJitter.awk out.tr
# == Programed By ==
# 查輝(ZHA HUI), Wuhan, China, Email: zhahui AT gmail.com
# == Description ==
# 本awk 程式給出了另外一種jitter的計算方法，這種方法中jitter 的計算是基于以下公式: 
# jitter ＝((recvtime(j)-sendtime(j))-(recvtime(i)-sendtime(i)))/(j-i), 其中 j>i 。 
# == Attention ==
# NormalJitter.awk中關於jitter 的計算完全基于柯志亨博士的measure-delay.awk程式中delay 的
# 計算。而measure-delay.awk 在柯博士網頁中的ns2類比例子中是正確的，但是對于不同的例子需要根
# 據情況進行一定的修改，並可能需要加入某些魯棒性處理代碼(例如對于第一個包的處理，對于丟包的處
# 理等) 。
# == Reference ==
# http://140.116.72.80/~smallko/ns2/ns2.htm
# == Feedback ==
# 如有任何關於本程式jitter 計算的問題，請致信 
# 柯志亨(ChihHeng, Ke) 博士 smallko2001 AT pchome.com.tw 或者與本人聯繫。 
# == Acknowledgements ==
# Dr. ChihHeng, Ke provided valuable documents and awk files upon my requests.
# ================================================================================
 
BEGIN {
#程式初始化，設定一變數以記錄目前最高處理封包的ID。
     highest_packet_id = 0;
}
{
   action = $1;
   time = $2;
   node_1 = $3;
   node_2 = $4;
   type = $5;
   flow_id = $8; 
   node_1_address = $9;
   node_2_address = $10; 
   seq_no = $11;
   packet_id = $12;
 
#記錄目前最高的packet ID
   if ( packet_id > highest_packet_id ) {
           highest_packet_id = packet_id;
        }
 
#記錄封包的傳送時間
   if ( start_time[packet_id] == 0 )  {
           # 記錄下包的 seq_no -- ZHA
           pkt_seqno[packet_id] = seq_no;
           start_time[packet_id] = time;
   }
 
#記錄CBR (flow_id=2) 的接收時間
   if ( flow_id == 2 && action != "d" ) {
      if ( action == "r" ) {
         end_time[packet_id] = time;
      }
   } else {
#把不是flow_id=2 的封包或者是flow_id=2但此封包被drop 的時間設為-1
      end_time[packet_id] = -1;
   }
}                                                        
END {
        # 初始化jitter計算所需變量 -- ZHA
        last_seqno = 0;
        last_delay = 0;
        seqno_diff = 0;
#當資料列全部讀取完後，開始計算有效封包的端點到端點延遲時間 
    for ( packet_id = 0; packet_id <= highest_packet_id; packet_id++ ) {
       start = start_time[packet_id];
       end = end_time[packet_id];
       packet_duration = end - start;
 
#只把接收時間大於傳送時間的記錄列出來
       if ( start < end ) {
               # 得到了 delay值(packet_duration)后計算 jitter -- ZHA
               seqno_diff = pkt_seqno[packet_id] - last_seqno;
               delay_diff = packet_duration - last_delay;
               if (seqno_diff == 0) {
                       jitter =0;
               } else {
                       jitter = delay_diff/seqno_diff;
               }
               printf("%f %f\n", start, jitter);
               last_seqno = pkt_seqno[packet_id];
               last_delay = packet_duration;
       }
    }
}

[Loss]

筆者把量測CBR Packet Loss的情況寫在檔案measure-drop.awk內。

BEGIN {

#程式初始化,設定一變數記錄packet被drop的數目

               fsDrops = 0;

               numFs = 0;

}

{

   action = $1;

   time = $2;

   node_1 = $3;

   node_2 = $4;

   src = $5;

   flow_id = $8;

   node_1_address = $9;

   node_2_address = $10;

   seq_no = $11;

   packet_id = $12;

#統計從n1送出多少packets

               if (node_1==1 && node_2==2 && action == "+")

                               numFs++;

#統計flow_id為2,且被drop的封包

               if (flow_id==2 && action == "d")

                               fsDrops++;

}

END {

               printf("number of packets sent:%d lost:%d\n", numFs, fsDrops);

}

執行方法: ($為shell的提示符號)

$awk -f measure-drop.awk out.tr

執行結果:

number of packets sent: 550  lost:8

這代表CBR送出了550個封包，但其中8個封包丟掉了。

[Throughput]

筆者把量測CBR Throughput的情況寫在檔案measure-throughput.awk內。在這裡的Throughput是指average throughput。

BEGIN {

               init=0;

               i=0;

}

{

               action = $1;

            time = $2;

            node_1 = $3;

            node_2 = $4;

            src = $5;

            pktsize = $6;

            flow_id = $8;

            node_1_address = $9;

            node_2_address = $10;

            seq_no = $11;

            packet_id = $12;

              if(action=="r" && node_1==2 && node_2==3 && flow_id==2) {

                              pkt_byte_sum[i+1]=pkt_byte_sum[i]+ pktsize;

                               if(init==0) {

                                              start_time = time;

                                              init = 1;

                               }

                               end_time[i] = time;

                               i = i+1;

               }

}

END {

#為了畫圖好看，把第一筆記錄的throughput設為零，以表示傳輸開始

               printf("%.2f\t%.2f\n", end_time[0], 0);

               for(j=1 ; j<i ; j++){

                               th = pkt_byte_sum[j] / (end_time[j] - start_time)*8/1000;

                               printf("%.2f\t%.2f\n", end_time[j], th);

               }

#為了畫圖好看，把第後一筆記錄的throughput再設為零，以表示傳輸結束

               printf("%.2f\t%.2f\n", end_time[i-1], 0);

}

執行方法: ($為shell的提示符號)

$awk -f measure-throughput.awk 
out.tr

若是要把結果存到檔案，可使用導向的方式。(把結果存到cbr_throughput檔案中)

$awk -f measure-throughput.awk 
out.tr > cbr_throughput